' Grosse Schriftarten

DECLARE SUB PrintGross (t$, xF%, yF%)

SCREEN 12

COLOR 3
PRINT "Grosser Text"
COLOR 7
PRINT "Mit normalem Text geht es los, ";
PrintGross "aber doppelt hoch", 1, 2
PRINT " ist lustiger! :-)"
PRINT "Oder wie w„re es mit ";
PrintGross "gesperrtem", 2, 1
PRINT " Text?"
PRINT
PRINT "Oder ";
PrintGross "ganz gross?", 2, 2
PRINT
PRINT
PRINT
PRINT " Oder ";
PrintGross "noch gr”sser? ;-)", 3, 3
PRINT " ?"
COLOR 13
PRINT
PrintGross " Ende mit Taste!", 2, 1

d$ = INPUT$(1)
SCREEN 0

SUB PrintGross (t$, xF%, yF%)
  IF t$ <> "" THEN
    DIM h%(1 + 32 * LEN(t$))
    ' Alter Ausschnitt sichern
    GET (0, 0)-(8 * LEN(t$) - 1, 15), h%
    xPo% = POS(0)
    yPo% = CSRLIN
    LOCATE 1, 1
    PRINT t$;
    xPo1% = xPo% * 8 - 8
    yPo1% = yPo% * 16 - 4 - 12 * yF%
    FOR y% = 0 TO 15
      FOR x% = 0 TO 8 * LEN(t$) - 1
        LINE (xPo1% + x% * xF%, yPo1% + y% * yF%)-STEP(xF% - 1, yF% - 1), POINT(x%, y%), BF
      NEXT x%
    NEXT y%
    ' Ausschnitt wiederherstellen
    PUT (0, 0), h%, PSET
    ERASE h%
    LOCATE yPo%, xPo% + LEN(t$) * xF%
  END IF
END SUB