' Datei auf Read-Only setzen
' $INCLUDE: 'qb.bi'

DIM dosIntEin AS RegTypeX, dosIntAus AS RegTypeX, puf AS STRING * 300

' Allgeines Vorgehen: Wir wollen nicht die Attribute komplett setzen,
' sondern im Sinne von "chmod +r" ein einzelnes Bit setzen. Daher mssen
' zuerst die bestehenden Bits gelesen werden

INPUT "Datei"; d$

' Dateiattribute lesen
' Quelle: http://www.ctyme.com/intr/rb-2802.htm
dosIntEin.ax = &H4300
puf = d$ + CHR$(0)
dosIntEin.ds = VARSEG(puf)
dosIntEin.dx = VARPTR(puf)
CALL INTERRUPTX(&H21, dosIntEin, dosIntAus)
IF dosIntAus.flags AND 1 THEN
	PRINT "Fehler beim Lesen der bisherigen Attribute:"; dosIntAus.ax
	END
ELSE
	attr% = dosIntAus.cx
END IF

' Read-Only setzen
attr% = attr% OR 1

' Dateiattribute setzen
' Quelle: http://www.ctyme.com/intr/rb-2803.htm
dosIntEin.ax = &H4301
dosIntEin.cx = attr%
puf = d$ + CHR$(0)
dosIntEin.ds = VARSEG(puf)
dosIntEin.dx = VARPTR(puf)
CALL INTERRUPTX(&H21, dosIntEin, dosIntAus)
IF dosIntAus.flags AND 1 THEN
	PRINT "Fehler beim Setezn der neuen Attribute:"; dosIntAus.ax
ELSE
	PRINT "Datei "; d$; " erfolgreich auf Nur-Lesen gesetzt"
END IF