100 ' Joystick-Justierprogramm (Analog-Joystick hardwarem„ssig kalibrieren)
110 ' Version 2 f�r das gleichzeitige Kalibrieren zweier Joysticks
120 :
130 SCREEN 9:CLS:KEY OFF
140 DIM K%(185),XR$(2),YR$(2),LX%(1),LY%(1),X1%(1),Y1%(1),LS%(1,1)
150 XR$(0)=" linke R."
160 XR$(1)=SPACE$(9)
170 XR$(2)="rechte R."
180 YR$(0)=" obere R."
190 YR$(1)=SPACE$(9)
200 YR$(2)="untere R."
210 LINE (15,0)-(15,22),15
220 LINE (0,11)-(30,11),15
230 GET (0,0)-(30,22),K%
240 CLS
250 FOR X%=0 TO 40 STEP 40:X1%=8*X%
260 LINE (15+X1%,11)-(270+X1%,266),11,B
270 LINE (143+X1%,11)-(143+X1%,266),3
280 LINE (15+X1%,96)-(270+X1%,96),5:LINE (15+X1%,181)-(270+X1%,181),2
290 LOCATE 10,5+X%:COLOR 12:PRINT "linke":LOCATE 11,4+X%:PRINT "Richtung"
300 LOCATE 10,27+X%:COLOR 9:PRINT "rechte":LOCATE 11,26+X%:PRINT "Richtung"
310 LINE (15+X1%,139)-(270+X1%,139),3
320 LINE (100+X1%,11)-(100+X1%,266),4:LINE (185+X1%,11)-(185+X1%,266),1
330 LOCATE 4,12+X%:COLOR 13:PRINT "obere Richtung"
340 LOCATE 16,12+X%:COLOR 10:PRINT "untere Rchtung"
350 COLOR 6:LOCATE 15,36+X%:PRINT "Port"
360 LOCATE 1,1:COLOR 14:PRINT CHR$(65+X%\40)
370 FOR I%=0 TO 13:FOR J%=0 TO 7:LINE (280+X1%+4*J%,210+4*I%)-STEP(3,3),POINT(J%,I%),BF:NEXT J%:NEXT I%
380 LINE (284+X1%,184)-STEP(32,-8):LINE -STEP(0,16):LINE -STEP(-32,-8):PAINT STEP(24,0)
390 LX%(X%\40)=128:LY%(X%\40)=128:X1%(X%\40)=-1:Y1%(X%\40)=-1:PUT (128+X1%,128),K%
400 NEXT X%
410 LOCATE 22,1:COLOR 14:PRINT "Bedienung dieses Joystickkalibierprogrammes:"
420 COLOR 7:PRINT "Regler solange drehen, bis sich das weisse Fadenkreuz genau auf der Mitte be-"
430 LOCATE 25,1:PRINT "ausschlagen. Ende mit beliebiger Taste. Feuerkn”pfe werden ebenfalls gepr�ft.";
440 LOCATE 24,1:PRINT "findet. Bei der Richtungsbet„tigung muss das Kreuz in die entsprechende Zone";
450 LOCATE 1,1:PRINT " ";
460 FOR I%=0 TO 1:X%=STICK(I%*2):Y%=STICK(I%*2+1):H%=40*I%
470 IF X%<>LX%(I%) OR Y%<>LY%(I%) THEN PUT (LX%(I%)+I%*320,LY%(I%)),K%:PUT (X%+I%*320,Y%),K%:LX%(I%)=X%:LY%(I%)=Y%:GOSUB 540
480 FOR J%=0 TO 1:F%=STRIG(I%*2+J%*4+1)
490 IF F% XOR LS%(I%,J%) THEN LOCATE 21,21+H%+10*J%:LS%(I%,J%)=F%:IF F% THEN COLOR 7+J%:PRINT "Feuerk. ";CHR$(49+J%); ELSE PRINT SPACE$(9);
500 NEXT J%:NEXT I%
510 IF INKEY$="" THEN 460
520 SYSTEM
530 :
540 XX%=1+(X%<85)-(X%>170):IF XX%<>X1%(I%) THEN COLOR 12+3*(XX%=2):LOCATE 21,1+H%:PRINT XR$(XX%);:X1%(I%)=XX%
550 YY%=1+(Y%<85)-(Y%>170):IF YY%<>Y1%(I%) THEN COLOR 13+3*(YY%=2):LOCATE 21,11+H%:PRINT YR$(YY%);:Y1%(I%)=YY%
560 RETURN