' Maustester

#Include "fbgfx.bi"

ScreenRes 640, 480, 4
Width 80, 30

Dim Shared fadenkreuz As FB.Image Ptr
fadenkreuz = ImageCreate(21, 21)
Line (10, 0)-(10, 20), 12
Line (0, 10)-(20, 10), 12
Get (0, 0)-(20, 20), fadenkreuz
Cls

Dim Shared xAlt As Integer = -100,  yAlt As Integer = -100, radAlt As Integer = -100, knoepfeAlt As Integer = -1, aussAlt As Integer = -1
Dim Shared x As Integer = 320, y As Integer = 320, rad As Integer = 0, knoepfe As Integer = 0, auss As Integer = 0

Sub AktualisiereWerte
	Dim h As Integer, i As Integer
		
	If x <> xAlt Or y <> yAlt Then
		Put (xAlt - 10, yAlt - 10), fadenkreuz, Xor
		Put (x - 10, y - 10), fadenkreuz, Xor
		xAlt = x
		yAlt = y
		Locate 1, 1
		Print Using "x:##### y:#####"; x; y
	EndIf
	If rad <> radAlt Then
		Locate 2, 1
		radAlt = rad
		Print Using "Mausrad: #####"; rad
	EndIf
	If knoepfe <> knoepfeAlt Then
		Locate 3, 1
		Print !"Kn\148pfe:";
		h = knoepfe
		For i=1 To 5
			If h And 1 Then
				Print !" \219\219";
			Else
				Print !" \176\176";
			EndIf
			h Shr= 1
		Next i
		knoepfeAlt = knoepfe
	EndIf
	If auss <> aussAlt Then
		Locate 4, 1
		Print Using "Clip: ####"; auss
		aussAlt = auss
	EndIf
End Sub

AktualisiereWerte
Do
	GetMouse x, y, rad, knoepfe, auss
	AktualisiereWerte
	Sleep 100
Loop Until InKey = !"\027"

Locate 6, 1
Print "Beende..."