' Einfache Spritedemo mit Animation

DIM Spr%(961), Msk%(961)

SCREEN 8

' Sprites zeichnen

Pi! = 4! * ATN(1!)
FOR y% = 0 TO 39
  y1! = CSNG(y%) - 19.5
  FOR x% = 0 TO 95
    x1! = CSNG(x%) - 47.5
    w! = 4! + ATN(x1! / y1! / 2.4) * 8! / Pi!
    IF y1! > 0! THEN
      w! = w! + 8!
    END IF
    r! = SQR(5.76 * y1! * y1! + x1! * x1!)
    f% = CINT(w! + r! / 10!) AND 15
    k! = ABS(w! - INT(w!) - .5) * 30!
    IF r! < 48! - k! THEN
      PSET (x%, y%), f%
      PSET (x% + 96, y%), 0
    ELSE
      PSET (x%, y%), 0
      PSET (x% + 96, y%), 15
    END IF
  NEXT x%
NEXT y%

GET (0, 0)-(95, 39), Spr%
GET (96, 0)-(191, 39), Msk%

' Statische Szene

CLS
FOR i% = 1 TO 200
  LINE (5 + CINT(630! * RND), 5 + CINT(190! * RND))-(5 + CINT(630! * RND), 5 + CINT(190! * RND)), 1 + CINT(INT(15! * RND))
NEXT i%
LOCATE 15, 10
PRINT "Noch etwas"
COLOR 4
LOCATE 16, 11
PRINT "farbigen"
COLOR 9
LOCATE 17, 12
PRINT "Text..."
FOR f% = 0 TO 15
  LINE (300 + 40 * (f% MOD 4), 70 + 30 * (f% \ 4))-STEP(39, 29), f%, BF
NEXT f%

' Ab hier Spriteanimation (Pfeiltasten)

x% = 136
y% = 80
pg% = 1
SCREEN , , 1, 1
DO
  PCOPY 0, pg%
  PUT (x%, y%), Msk%, AND
  PUT (x%, y%), Spr%, XOR
  SCREEN , , 3 - pg%, pg%
  DO
    t$ = INKEY$
  LOOP WHILE t$ = ""
  SELECT CASE t$
  CASE CHR$(0) + "H"
    IF y% > 0 THEN
      y% = y% - 1
    END IF
  CASE CHR$(0) + "K"
    IF x% > 0 THEN
      x% = x% - 1
    END IF
  CASE CHR$(0) + "M"
    IF x% < 544 THEN
      x% = x% + 1
    END IF
  CASE CHR$(0) + "P"
    IF y% < 160 THEN
      y% = y% + 1
    END IF
  END SELECT
  pg% = 3 - pg%
LOOP UNTIL t$ = CHR$(27)

SCREEN 0
WIDTH 80, 25